build.gradle

/*
 Copyright 2015 Battams, Derek
 
	Licensed under the Apache License, Version 2.0 (the "License");
	you may not use this file except in compliance with the License.
	You may obtain a copy of the License at
 
		http://www.apache.org/licenses/LICENSE-2.0
 
	Unless required by applicable law or agreed to in writing, software
	distributed under the License is distributed on an "AS IS" BASIS,
	WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
	See the License for the specific language governing permissions and
	limitations under the License.
*/

plugins {
	id 'groovy'
	id 'war'
	id 'eclipse'
	id 'net.nemerosa.versioning' version '1.3.0'
}

war {
	archiveName = 'summarize.war'
}

versioning {
	releaseMode = 'snapshot'
}

versionFile {
	def props = new File(sourceSets.main.resources.srcDirs[0], 'summarize.properties')
	outputs.file props
	outputs.upToDateWhen { false }
	file = props
}

group = 'com.github.slugger.summarize'
version = versioning.info.display
sourceCompatibility = '1.7'

repositories {
	mavenCentral()
	jcenter()
}

dependencies {
	providedCompile 'org.eclipse.jetty:jetty-server:8.1.16.v20140903'
	providedCompile 'org.eclipse.jetty:jetty-servlet:8.1.16.v20140903'
	providedCompile 'org.eclipse.jetty:jetty-jsp:8.1.16.v20140903'

	compile 'org.codehaus.groovy:groovy-all:2.3.11'
	compile 'log4j:log4j:1.2.17'
	runtime 'org.apache.derby:derby:10.11.1.1'
	//testCompile 'org.powermock:powermock-module-junit4:1.5.4'
	//testCompile 'org.powermock:powermock-api-mockito:1.5.4'
}

task cpWarToDocker(type: Copy) {
	def outDir = new File(project.buildDir, 'docker/war')
	dependsOn war
	from(new File(project.buildDir, 'libs').absolutePath) {
		include war.archiveName
	}
	into(outDir.absolutePath)
	outputs.files(new File(outDir, war.archiveName))
}

task setupDockerEnv(type: Copy) {
	from(new File(project.projectDir, 'docker'))
	into(new File(project.buildDir, 'docker'))
}

task mkDockerImg(type: Exec) {
	dependsOn setupDockerEnv, cpWarToDocker
	workingDir = new File(project.buildDir, 'docker')
	commandLine 'docker', 'build', '-t', 'slugger/summarize', '.'
	doFirst {
		if(!System.getProperty('os.name').toLowerCase().contains('linux'))
			throw new UnsupportedOperationException('Can only build docker images on Linux!')
	}
}

compileJava.dependsOn versionFile