Arch AUR Package

[matthewhague]

I found this via the issue on the SSR repository. Thanks for your work on this, it's very useful while waiting for an official solution.

I adapted the simplescreenrecorder-git Arch Linux AUR package to install this version. Would it make sense to add this to the AUR, or is it too unstable at the moment?

If adding it makes sense, would you mind me checking the dependencies etc with you before i add it (just to make sure i didn't miss anything)?

[foxcpp]

Multi-monitor support is partially (or fully?) broken. Select Region and Selection Window buttons are disabled. But it can record video. I use it myself and haven't found any issues so far. Feel free to create the AUR package if you want. Except, probably, add me as a co-maintainer? :)

[matthewhague]

I think that's ok -- given the lack of even basic support outside of green-recorder. I've included "experimental" in the package description to manage expectations.

Here is the PKGBUILD. I'm not sure about the dependencies: are the X11 dependencies still needed? Is wlroots the only Wayland related dependency?

# Maintainer: Matthew Hague <[email protected]>
# Maintainer: Max Mazurov <[email protected]>
# Based on PKGBUILD/install by: Maarten Baert <[email protected]>

pkgname=simplescreenrecorder-wlroots-git
pkgver=0.3.11.r23.g4b288cb
pkgrel=1
pkgdesc="Experimental fork of simplescreenrecorder for wlroots (e.g. Sway)"
arch=("x86_64")
url="https://github.com/foxcpp/ssr-wlroots"
license=("GPL3")
depends=("qt5-base" "qt5-x11extras"
    "ffmpeg" "alsa-lib" "libpulse" "jack" "libgl" "glu"
    "libx11" "libxext" "libxfixes" "libxi"
    "desktop-file-utils" "gtk-update-icon-cache"
    "wlroots")
makedepends=("git" "cmake" "qt5-tools")
source=("git+https://github.com/foxcpp/ssr-wlroots")
md5sums=("SKIP")
conflicts=("simplescreenrecorder" "simplescreenrecorder-git")
provides=("simplescreenrecorder")

install=simplescreenrecorder-wlroots-git.install

pkgver() {
	cd ssr-wlroots
	# Use the tag of the last commit
	git describe --long | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
	cd ssr-wlroots
	mkdir -p build
}
build() {
	cd ssr-wlroots/build
	cmake -DCMAKE_INSTALL_PREFIX="/usr" -DCMAKE_INSTALL_LIBDIR="lib" -DCMAKE_BUILD_TYPE=Release -DWITH_QT5=TRUE ..
	make
}
package() {
	cd ssr-wlroots/build
	make DESTDIR="$pkgdir" install
}

[foxcpp]

See https://github.com/foxcpp/ssr-wlroots#build-dependencies.

• wayland package for libwayland-client.
• wayland-protocols in makedepends for xdg-output protocol definition.
  wlroots is not needed.

[foxcpp]

And X11 dependencies are still needed because this fork works both with X11 and Wayland.

[matthewhague]

Cool, thanks (i should have seen the deps in the README, sorry). I'll update the description to "simplescreenrecorder with experimental Wayland support".

[matthewhague]

Package now available here.

[foxcpp]

Co-maintainer access for me? https://aur.archlinux.org/pkgbase/simplescreenrecorder-wlroots-git/comaintainers

[matthewhague]

I think that's done now (bit distracted -- doing this while watching Milan-San Remo :) ).

[foxcpp]

Thanks.